/[qa]/trunk/pts/www/xsl/pts.xsl
ViewVC logotype

Contents of /trunk/pts/www/xsl/pts.xsl

Parent Directory Parent Directory | Revision Log Revision Log

Revision 2669 - (show annotations) (download) (as text)
Sat Nov 26 14:11:57 2011 UTC (17 months, 3 weeks ago) by pabs
File MIME type: application/xml
File size: 48948 byte(s) 
Link to the new build log check system (Closes: #650039)

Patch by Bernhard R. Link
1 <?xml version="1.0" encoding="utf-8" ?>
2
3 <!--
4 # Copyright © 2002-2011 Raphaël Hertzog and others
5 # Copyright © 2007-2009 Stefano Zacchiroli
6 # This file is distributed under the terms of the General Public License
7 # version 2 or (at your option) any later version.
8 -->
9
10 <xsl:stylesheet
11 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
12 xmlns="http://www.w3.org/1999/xhtml"
13 xmlns:str="http://exslt.org/strings"
14 version="1.0">
15
16 <xsl:output
17 method="xml"
18 encoding="UTF-8"
19 omit-xml-declaration="yes"
20 doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN"
21 doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd"
22 indent="yes" />
23
24 <xsl:include href="pts-issues.xsl" />
25
26 <xsl:param name="package"/>
27 <xsl:param name="dir"/>
28 <xsl:param name="date"/>
29 <xsl:param name="hasoldstable" select="''"/>
30 <xsl:param name="hasstable" select="''"/>
31 <xsl:param name="hastesting" select="''"/>
32 <xsl:param name="hasunstable" select="''"/>
33 <xsl:param name="hasexperimental" select="''"/>
34 <xsl:param name="hasmentors" select="''"/>
35 <xsl:param name="hasother" select="''"/>
36 <xsl:param name="hasstable-proposed-updates" select="''"/>
37 <xsl:param name="hastesting-proposed-updates" select="''"/>
38 <xsl:param name="hassecurity-oldstable" select="''"/>
39 <xsl:param name="hassecurity-stable" select="''"/>
40 <xsl:param name="hassecurity-testing" select="''"/>
41 <xsl:param name="hasoldstable-updates" select="''"/>
42 <xsl:param name="hasstable-updates" select="''"/>
43 <xsl:param name="hasoldstable-backports" select="''"/>
44 <xsl:param name="hasstable-backports" select="''"/>
45 <xsl:param name="hasnews" select="''"/>
46 <xsl:param name="hasexcuse" select="''"/>
47
48 <xsl:variable name="other"
49 select="document(concat('../base/', $dir, '/other.xml'))/other"/>
50 <xsl:variable name="low-nmu-emails"
51 select="document('../base/low_threshold_nmu.emails.xml')/emails"/>
52 <xsl:variable name="mostrecentsuite">
53 <!-- name of the most recent suite in which the package is available
54 -->
55 <xsl:choose>
56 <xsl:when test="$hasexperimental">
57 <xsl:text>experimental</xsl:text>
58 </xsl:when>
59 <xsl:when test="$hasunstable">
60 <xsl:text>unstable</xsl:text>
61 </xsl:when>
62 <xsl:when test="$hastesting">
63 <xsl:text>testing</xsl:text>
64 </xsl:when>
65 <xsl:when test="$hasstable">
66 <xsl:text>stable</xsl:text>
67 </xsl:when>
68 <xsl:otherwise>
69 <xsl:text />
70 </xsl:otherwise>
71 </xsl:choose>
72 </xsl:variable>
73 <xsl:variable name="pooldir">
74 <xsl:if test="$mostrecentsuite != ''">
75 <xsl:value-of
76 select="document(concat('../base/', $dir, '/',
77 $mostrecentsuite, '.xml'))/source/directory" />
78 </xsl:if>
79 </xsl:variable>
80
81 <!-- Those variables controls the todo and problem item concerning
82 standards-version not being up to date -->
83 <xsl:variable name="lastsv" select="'3.9.2'"/>
84 <xsl:variable name="lastmajorsv" select="'3.'"/>
85
86 <!-- lintian summary -->
87 <xsl:variable name="lin_errs" select="$other/lintian/@errors" />
88 <xsl:variable name="lin_warns" select="$other/lintian/@warnings" />
89
90 <!-- buildd log check summary -->
91 <xsl:variable name="logcheck_errs" select="$other/logcheck/@errors" />
92 <xsl:variable name="logcheck_warns" select="$other/logcheck/@warnings" />
93
94 <!-- Named templates aka functions -->
95
96 <xsl:template name="mk_lintian_url">
97 <!-- convert maintainer/name to follow lintian.debian.org convention -->
98 <xsl:variable name="lintian_pattern" select="concat('àáèéëêòöøîìùñ~/()&#34; ', &quot;'&quot;)"/>
99 <xsl:variable name="lintian_email" select="translate(maintainer/email, $lintian_pattern, '_____________________')"/>
100
101 <xsl:text>http://lintian.debian.org/maintainer/</xsl:text>
102 <xsl:value-of select="$lintian_email" />
103 <xsl:text>.html#</xsl:text>
104 <xsl:value-of select="$package" />
105 </xsl:template>
106
107 <xsl:template name="mk_logcheck_url">
108 <xsl:text>http://buildd.debian.org/~brlink/packages/</xsl:text>
109 <xsl:value-of select="substring($package,1,1)"/>
110 <xsl:text>/</xsl:text>
111 <xsl:value-of select="$package" />
112 <xsl:text>.html</xsl:text>
113 </xsl:template>
114
115 <xsl:variable name="mirror">http://cdn.debian.net/debian</xsl:variable>
116 <xsl:variable name="security-mirror">http://security.debian.org/debian-security</xsl:variable>
117 <xsl:variable name="backports-mirror">http://backports.debian.org/debian-backports</xsl:variable>
118
119 <xsl:template name="outputitem">
120 <xsl:choose>
121 <xsl:when test="@url">
122 <li><xsl:if test="@date">
123 <xsl:text>[</xsl:text>
124 <xsl:value-of select="@date"/>
125 <xsl:text>] </xsl:text>
126 </xsl:if><a href="{@url}">
127 <xsl:value-of select="text()"/></a><xsl:if test="@from">
128 <xsl:text> (</xsl:text>
129 <xsl:value-of select="@from"/>
130 <xsl:text>)</xsl:text></xsl:if></li>
131 </xsl:when>
132 <xsl:when test="@type='raw'">
133 <li>
134 <xsl:copy-of select="node()" />
135 </li>
136 </xsl:when>
137 <xsl:otherwise>
138 <li><xsl:if test="@date">
139 <xsl:text>[</xsl:text>
140 <xsl:value-of select="@date"/>
141 <xsl:text>] </xsl:text>
142 </xsl:if><xsl:value-of select="text()"/></li>
143 </xsl:otherwise>
144 </xsl:choose>
145 </xsl:template>
146
147 <!-- Convert + in %2b for URL escaping. Should actually first also do
148 other-to-%xx, especially % to %25... Fortunately, that's rare -->
149 <xsl:template name="escape-name">
150 <xsl:param name="text"/>
151 <xsl:if test="contains($text,'+')">
152 <xsl:value-of select="substring-before($text,'+')"/>
153 <xsl:text>%2b</xsl:text>
154 <xsl:call-template name="escape-name">
155 <xsl:with-param name="text"><xsl:value-of select="substring-after($text,'+')"/></xsl:with-param>
156 </xsl:call-template>
157 </xsl:if>
158 <xsl:if test="not(contains($text,'+'))">
159 <xsl:value-of select="$text"/>
160 </xsl:if>
161 </xsl:template>
162
163 <xsl:variable name="escaped-package">
164 <xsl:call-template name="escape-name">
165 <xsl:with-param name="text"><xsl:value-of select="$package"/></xsl:with-param>
166 </xsl:call-template>
167 </xsl:variable>
168
169 <!-- Strip epoch -->
170 <xsl:template name="strip-epoch">
171 <xsl:param name="version"/>
172 <xsl:if test="contains($version,':')">
173 <xsl:value-of select="substring-after($version,':')"/>
174 </xsl:if>
175 <xsl:if test="not(contains($version,':'))">
176 <xsl:value-of select="$version"/>
177 </xsl:if>
178 </xsl:template>
179
180 <xsl:template name="add-vcs-info">
181 <xsl:if test="repository">
182 <dt title="Version Control System">VCS</dt>
183 <dd>
184 <xsl:if test="repository/vcs[@kind!='browser']">
185 <xsl:for-each select="repository/vcs[@kind!='browser']">
186 <xsl:sort select="@kind" />
187 <a title="raw {@kind} repository" href="{@url}">
188 <xsl:value-of select="@kind" />
189 </a>
190 <xsl:if test="position()!=last()"><xsl:text>, </xsl:text></xsl:if>
191 </xsl:for-each>
192 </xsl:if>
193 <xsl:if test="repository/vcs[@kind='browser']">
194 <xsl:text> (</xsl:text>
195 <a title="browse the repository"
196 href="{repository/vcs[@kind='browser']/@url}">browse</a>
197 <xsl:text>)</xsl:text>
198 </xsl:if>
199 </dd>
200 </xsl:if>
201 </xsl:template>
202
203 <xsl:template name="add-maintenance-info">
204 <xsl:param name="email" />
205 <xsl:variable name="dm">
206 <xsl:if test="dm-upload-allowed and string(dm-upload-allowed)='yes'">
207 <xsl:text>true</xsl:text>
208 </xsl:if>
209 </xsl:variable>
210 <xsl:variable name="lownmu">
211 <xsl:if test="$low-nmu-emails/email[text()=$email]">
212 <xsl:text>true</xsl:text>
213 </xsl:if>
214 </xsl:variable>
215
216 <xsl:if test="string($dm)!='' or string($lownmu)!=''">
217 <div class="maint-markers">
218 <xsl:if test="string($dm)!=''">
219 <span class="dm-tag">
220 <a href="http://www.debian.org/vote/2007/vote_003">
221 <acronym title="Debian Maintainer Upload Allowed: this package can be uploaded by Debian Maintainers">DMUA</acronym>
222 </a>
223 </span>
224 </xsl:if>
225 <xsl:if test="string($lownmu)!=''">
226 <xsl:if test="string($dm)!=''">
227 <xsl:text>, </xsl:text>
228 </xsl:if>
229 <span class="lownmu-tag">
230 <a href="http://wiki.debian.org/LowThresholdNmu">
231 <acronym title="maintainer agrees with Low Threshold NMU">LowNMU</acronym>
232 </a>
233 </span>
234 </xsl:if>
235 </div>
236 </xsl:if>
237 </xsl:template>
238
239 <xsl:template name="output-news">
240 <xsl:param name="news" />
241
242 <xsl:if test="count($news)>0 and string($news)!=''">
243 <div class="block news">
244 <a name="news" />
245 <h2>news <a class="feedlink" href="{$package}/news.rss20.xml">RSS</a></h2>
246 <ul id="news-list">
247 <xsl:copy-of select="$news" />
248 </ul>
249 </div>
250 </xsl:if>
251 </xsl:template>
252
253 <xsl:template name="output-static">
254 <xsl:param name="static" />
255
256 <xsl:if test="count($static)>0 and string($static)!=''">
257 <div class="block static">
258 <a name="static" />
259 <h2>static info</h2>
260 <ul>
261 <xsl:copy-of select="$static" />
262 </ul>
263 </div>
264 </xsl:if>
265 </xsl:template>
266
267 <xsl:template name="maintainer-email">
268 <xsl:param name="email" />
269 <a class="email" href="mailto:{$email}">
270 <img alt="[email]" src="../common/email.png" title="email" />
271 </a>
272 </xsl:template>
273
274 <xsl:template name="general-information">
275 <div class="block info">
276 <a name="general" />
277 <h2>general</h2>
278 <dl>
279 <dt>source</dt>
280 <dd>
281 <a href="http://packages.debian.org/src:{$package}">
282 <xsl:value-of select="$package" />
283 </a>
284 (<span id="priority" title="priority">
285 <small><xsl:value-of select="priority"/></small>
286 </span>,
287 <span id="section" title="section">
288 <small><xsl:value-of select="section"/></small>
289 </span>)
290 </dd>
291
292 <dt>version</dt>
293 <dd>
294 <span id="latest_version"><xsl:value-of select="version"/></span>
295 </dd>
296
297 <xsl:if test="@release!='unstable'">
298 <dt>distro</dt>
299 <dd><xsl:value-of select="@release"/></dd>
300 </xsl:if>
301
302 <dt title="Maintainer and Uploaders">maint</dt>
303 <dd class="maintainer">
304 <xsl:element name="a">
305 <xsl:attribute name="href">
306 <xsl:text>http://qa.debian.org/developer.php?login=</xsl:text>
307 <xsl:call-template name="escape-name">
308 <xsl:with-param name="text"><xsl:value-of select="maintainer/email"/></xsl:with-param>
309 </xsl:call-template>
310 </xsl:attribute>
311 <span class="name" title="maintainer">
312 <xsl:value-of select="maintainer/name"/>
313 </span>
314 </xsl:element>
315 <xsl:if test="uploaders">
316 <xsl:for-each select="uploaders/item">
317 <xsl:text>, </xsl:text>
318 <span class="uploader">
319 <small>
320 <xsl:element name="a">
321 <xsl:attribute name="href">
322 <xsl:text>http://qa.debian.org/developer.php?login=</xsl:text>
323 <xsl:call-template name="escape-name">
324 <xsl:with-param name="text">
325 <xsl:value-of select="email"/>
326 </xsl:with-param>
327 </xsl:call-template>
328 </xsl:attribute>
329 <span class="name" title="uploader">
330 <xsl:value-of select="name"/>
331 </span>
332 </xsl:element>
333 <xsl:text> (u)</xsl:text>
334 </small>
335 </span>
336 </xsl:for-each>
337 </xsl:if>
338 <xsl:call-template name='add-maintenance-info'>
339 <xsl:with-param name="email" select="maintainer/email" />
340 </xsl:call-template>
341 </dd>
342
343 <xsl:if test="architecture!='any' and architecture!='all'">
344 <dt>arch</dt>
345 <dd><xsl:value-of select="architecture"/></dd>
346 </xsl:if>
347
348 <dt title="Standards-Version">std-ver</dt>
349 <dd>
350 <span id="standards_version">
351 <xsl:value-of select="standards-version"/>
352 </span>
353 </dd>
354
355 <xsl:call-template name='add-vcs-info' />
356 </dl>
357 </div>
358 </xsl:template>
359
360 <xsl:template name="bugs-count">
361 <div class="block bugs">
362 <a name="bugs" />
363 <h2>bugs</h2>
364 <dl>
365 <dt id="bugs_all">
366 all
367 <xsl:element name="a">
368 <xsl:attribute name="href">
369 <xsl:text>http://qa.debian.org/data/bts/graphs/</xsl:text>
370 <xsl:value-of select="$dir"/>
371 <xsl:text>.png</xsl:text>
372 </xsl:attribute>
373 <xsl:attribute name="title">bug history graph</xsl:attribute>
374 <img alt="bug history graph" src="../common/bug-graph.png" />
375 </xsl:element>
376 </dt>
377 <dd>
378 <xsl:element name="a">
379 <xsl:attribute name="href">
380 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?repeatmerged=no&amp;src=</xsl:text>
381 <xsl:value-of select="$escaped-package" />
382 </xsl:attribute>
383 <xsl:if test="$hasother">
384 <span class="bugcount" title="all">
385 <xsl:value-of select="$other/bugs/@all"/>
386 </span>
387 </xsl:if>
388 </xsl:element>
389 <xsl:if test="$hasother and $other/bugs/@all_m">
390 (<xsl:element name="a">
391 <xsl:attribute name="href">
392 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?repeatmerged=yes&amp;src=</xsl:text>
393 <xsl:value-of select="$escaped-package" />
394 </xsl:attribute>
395 <xsl:value-of select="$other/bugs/@all_m"/>
396 </xsl:element>)
397 </xsl:if>
398 </dd>
399 <dt id="bugs_rc" title="Release Critical">
400 <span class="indented">RC</span>
401 </dt>
402 <dd>
403 <xsl:element name="a">
404 <xsl:attribute name="href">
405 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?src=</xsl:text>
406 <xsl:value-of select="$escaped-package" />
407 <xsl:text>&amp;archive=no&amp;pend-exc=pending-fixed&amp;pend-exc=fixed&amp;pend-exc=done&amp;sev-inc=critical&amp;sev-inc=grave&amp;sev-inc=serious&amp;repeatmerged=no</xsl:text>
408 </xsl:attribute>
409 <xsl:if test="$hasother">
410 <span class="bugcount" title="rc">
411 <xsl:value-of select="$other/bugs/@rc"/>
412 </span>
413 </xsl:if>
414 </xsl:element>
415 <xsl:if test="$hasother and $other/bugs/@rc_m">
416 (<xsl:element name="a">
417 <xsl:attribute name="href">
418 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?src=</xsl:text>
419 <xsl:value-of select="$escaped-package" />
420 <xsl:text>&amp;archive=no&amp;pend-exc=pending-fixed&amp;pend-exc=fixed&amp;pend-exc=done&amp;sev-inc=critical&amp;sev-inc=grave&amp;sev-inc=serious&amp;repeatmerged=yes</xsl:text>
421 </xsl:attribute>
422 <xsl:value-of select="$other/bugs/@rc_m"/>
423 </xsl:element>)
424 </xsl:if>
425 </dd>
426 <dt id="bugs_in" title="Important and Normal">
427 <span class="indented">I&amp;N</span>
428 </dt>
429 <dd>
430 <xsl:element name="a">
431 <xsl:attribute name="href">
432 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?src=</xsl:text>
433 <xsl:value-of select="$escaped-package" />
434 <xsl:text>&amp;archive=no&amp;pend-exc=pending-fixed&amp;pend-exc=fixed&amp;pend-exc=done&amp;sev-inc=important&amp;sev-inc=normal&amp;repeatmerged=no</xsl:text>
435 </xsl:attribute>
436 <xsl:if test="$hasother">
437 <span class="bugcount" title="in">
438 <xsl:value-of select="$other/bugs/@normal"/>
439 </span>
440 </xsl:if>
441 </xsl:element>
442 <xsl:if test="$hasother and $other/bugs/@normal_m">
443 (<xsl:element name="a">
444 <xsl:attribute name="href">
445 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?src=</xsl:text>
446 <xsl:value-of select="$escaped-package" />
447 <xsl:text>&amp;archive=no&amp;pend-exc=pending-fixed&amp;pend-exc=fixed&amp;pend-exc=done&amp;sev-inc=important&amp;sev-inc=normal&amp;repeatmerged=yes</xsl:text>
448 </xsl:attribute>
449 <xsl:value-of select="$other/bugs/@normal_m"/>
450 </xsl:element>)
451 </xsl:if>
452 </dd>
453 <dt id="bugs_mw" title="Minor and Wishlist">
454 <span class="indented">M&amp;W</span>
455 </dt>
456 <dd>
457 <xsl:element name="a">
458 <xsl:attribute name="href">
459 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?src=</xsl:text>
460 <xsl:value-of select="$escaped-package" />
461 <xsl:text>&amp;archive=no&amp;pend-exc=pending-fixed&amp;pend-exc=fixed&amp;pend-exc=done&amp;sev-inc=minor&amp;sev-inc=wishlist&amp;repeatmerged=no</xsl:text>
462 </xsl:attribute>
463 <xsl:if test="$hasother">
464 <span class="bugcount" title="mw">
465 <xsl:value-of select="$other/bugs/@wishlist"/>
466 </span>
467 </xsl:if>
468 </xsl:element>
469 <xsl:if test="$hasother and $other/bugs/@wishlist_m">
470 (<xsl:element name="a">
471 <xsl:attribute name="href">
472 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?src=</xsl:text>
473 <xsl:value-of select="$escaped-package" />
474 <xsl:text>&amp;archive=no&amp;pend-exc=pending-fixed&amp;pend-exc=fixed&amp;pend-exc=done&amp;sev-inc=minor&amp;sev-inc=wishlist&amp;repeatmerged=yes</xsl:text>
475 </xsl:attribute>
476 <xsl:value-of select="$other/bugs/@wishlist_m"/>
477 </xsl:element>)
478 </xsl:if>
479 </dd>
480 <dt id="bugs_fp" title="Fixed and Pending">
481 <span class="indented">F&amp;P</span>
482 </dt>
483 <dd>
484 <xsl:element name="a">
485 <xsl:attribute name="href">
486 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?src=</xsl:text>
487 <xsl:value-of select="$escaped-package" />
488 <xsl:text>&amp;archive=no&amp;pend-inc=pending-fixed&amp;pend-inc=fixed&amp;repeatmerged=no</xsl:text>
489 </xsl:attribute>
490 <xsl:if test="$hasother">
491 <span class="bugcount" title="fp">
492 <xsl:value-of select="$other/bugs/@fixed"/>
493 </span>
494 </xsl:if>
495 </xsl:element>
496 <xsl:if test="$hasother and $other/bugs/@fixed_m">
497 (<xsl:element name="a">
498 <xsl:attribute name="href">
499 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?src=</xsl:text>
500 <xsl:value-of select="$escaped-package" />
501 <xsl:text>&amp;archive=no&amp;pend-inc=pending-fixed&amp;pend-inc=fixed&amp;repeatmerged=yes</xsl:text>
502 </xsl:attribute>
503 <xsl:value-of select="$other/bugs/@fixed_m"/>
504 </xsl:element>)
505 </xsl:if>
506 </dd>
507 <xsl:if test="$other/bugs/@gift &gt; 0">
508 <dt id="bugs_gift">
509 <span class="indented">
510 <a href="http://wiki.debian.org/qa.debian.org/GiftTag">gift</a>
511 </span>
512 </dt>
513 <dd>
514 <xsl:element name="a">
515 <xsl:attribute name="href">
516 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?src=</xsl:text>
517 <xsl:value-of select="$escaped-package" />
518 <xsl:text>&amp;users=debian-qa@lists.debian.org;tag=gift</xsl:text>
519 </xsl:attribute>
520 <span class="bugcount" title="gift">
521 <xsl:value-of select="$other/bugs/@gift" />
522 </span>
523 </xsl:element>
524 </dd>
525 </xsl:if>
526 </dl>
527 </div>
528 </xsl:template>
529
530 <xsl:template name="pts-subscription">
531 <!-- <acronym title="Package Tracking System">PTS</acronym> subscription -->
532 <!-- <tr class="normalrow"> -->
533 <!-- <td class="labelcell">Subscribers count</td> -->
534 <!-- <td class="contentcell"><xsl:if test="$hasother"> -->
535 <!-- <xsl:value-of select="$other/pts/@count"/> -->
536 <!-- </xsl:if></td> -->
537 <!-- </tr> -->
538 <form method="post" action="/cgi-bin/pts.cgi">
539 <p>
540 <input type="hidden" name="package" value="{$package}"/>
541 subscribe to this package<br />
542 <input type="text" name="email" size="10" value="email"
543 onfocus="if(email.value=='your email'){{email.value=''}}"/>
544 <select name="what">
545 <option value="subscribe">sub</option>
546 <option value="unsubscribe">unsub</option>
547 <option value="advanced">opts</option>
548 </select>
549 <input type="submit" name="submit" value="go"/>
550 </p>
551 </form>
552 </xsl:template>
553
554 <xsl:template name="binary-packages">
555 <div class="block binaries">
556 <a name="binaries" />
557 <h2>binaries</h2>
558 <ul>
559 <xsl:for-each select="binary/item">
560 <xsl:sort select="text()"/>
561 <xsl:variable name="pkg" select="text()"/>
562 <xsl:variable name="tooltip"
563 select="concat($pkg, ': ',
564 $other/descriptions/shortdesc[@package=$pkg])" />
565 <li class="binpkg">
566 <a class="binpkg" title="{$tooltip}"
567 href="http://packages.debian.org/{text()}">
568 <span class="binpkg"><xsl:value-of select="text()"/></span>
569 </a>
570 <span style="font-size: 70%">
571 (<a href="http://bugs.debian.org/{text()}"><xsl:value-of select="$other/bugs/item[@name=$pkg]/@all"/> bugs</a>:
572 <xsl:element name="a">
573 <xsl:attribute name="title">critical, grave and serious</xsl:attribute>
574 <xsl:attribute name="href">
575 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?which=pkg&amp;data=</xsl:text>
576 <xsl:call-template name="escape-name">
577 <xsl:with-param name="text"><xsl:value-of select="text()"/></xsl:with-param>
578 </xsl:call-template>
579 <xsl:text>&amp;archive=no&amp;pend-exc=pending-fixed&amp;pend-exc=fixed&amp;pend-exc=done&amp;sev-inc=critical&amp;sev-inc=grave&amp;sev-inc=serious</xsl:text>
580 </xsl:attribute>
581 <xsl:value-of select="$other/bugs/item[@name=$pkg]/@rc"/>
582 </xsl:element>,
583 <xsl:element name="a">
584 <xsl:attribute name="title">important and normal</xsl:attribute>
585 <xsl:attribute name="href">
586 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?which=pkg&amp;data=</xsl:text>
587 <xsl:call-template name="escape-name">
588 <xsl:with-param name="text"><xsl:value-of select="text()"/></xsl:with-param>
589 </xsl:call-template>
590 <xsl:text>&amp;archive=no&amp;pend-exc=pending-fixed&amp;pend-exc=fixed&amp;pend-exc=done&amp;sev-inc=important&amp;sev-inc=normal</xsl:text>
591 </xsl:attribute>
592 <xsl:value-of select="$other/bugs/item[@name=$pkg]/@normal"/>
593 </xsl:element>,
594 <xsl:element name="a">
595 <xsl:attribute name="title">wishlist and minor</xsl:attribute>
596 <xsl:attribute name="href">
597 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?which=pkg&amp;data=</xsl:text>
598 <xsl:call-template name="escape-name">
599 <xsl:with-param name="text"><xsl:value-of select="text()"/></xsl:with-param>
600 </xsl:call-template>
601 <xsl:text>&amp;archive=no&amp;pend-exc=pending-fixed&amp;pend-exc=fixed&amp;pend-exc=done&amp;sev-inc=minor&amp;sev-inc=wishlist</xsl:text>
602 </xsl:attribute>
603 <xsl:value-of select="$other/bugs/item[@name=$pkg]/@wishlist"/>
604 </xsl:element>,
605 <xsl:element name="a">
606 <xsl:attribute name="title">pending and fixed</xsl:attribute>
607 <xsl:attribute name="href">
608 <xsl:text>http://bugs.debian.org/cgi-bin/pkgreport.cgi?which=pkg&amp;data=</xsl:text>
609 <xsl:call-template name="escape-name">
610 <xsl:with-param name="text"><xsl:value-of select="text()"/></xsl:with-param>
611 </xsl:call-template>
612 <xsl:text>&amp;archive=no&amp;pend-inc=pending-fixed&amp;pend-inc=fixed</xsl:text>
613 </xsl:attribute>
614 <xsl:value-of select="$other/bugs/item[@name=$pkg]/@fixed"/>
615 </xsl:element>)
616 </span>
617 </li>
618 </xsl:for-each>
619 </ul>
620 </div>
621 </xsl:template>
622
623 <xsl:template name="output-version">
624 <xsl:param name="suite" select="''" />
625 <xsl:param name="link" select="'yes'" />
626 <xsl:variable name="version">
627 <span class="srcversion" title="{$suite}">
628 <xsl:value-of select="document(concat('../base/', $dir, '/', $suite,
629 '.xml'))/source/version"/>
630 </span>
631 </xsl:variable>
632 <xsl:choose>
633 <xsl:when test="$link='yes'">
634 <xsl:element name="a">
635 <xsl:attribute name="class">dsc</xsl:attribute>
636 <xsl:attribute name="href">
637 <xsl:choose>
638 <xsl:when test="starts-with($suite, 'security-')">
639 <xsl:value-of select="$security-mirror"/>
640 <xsl:text>/</xsl:text>
641 <xsl:value-of
642 select="document(concat('../base/', $dir, '/',
643 $suite, '.xml'))/source/directory" />
644 </xsl:when>
645 <xsl:when test="str:replace($suite, '-backports', '') != $suite">
646 <xsl:value-of select="$backports-mirror"/>
647 <xsl:text>/</xsl:text>
648 <xsl:value-of
649 select="document(concat('../base/', $dir, '/',
650 $suite, '.xml'))/source/directory" />
651 </xsl:when>
652 <xsl:otherwise>
653 <xsl:value-of select="$mirror"/>
654 <xsl:text>/</xsl:text>
655 <xsl:value-of select="$pooldir"/>
656 </xsl:otherwise>
657 </xsl:choose>
658 <xsl:text>/</xsl:text>
659 <xsl:value-of select="document(concat('../base/', $dir, '/',
660 $suite, '.xml'))/source/files/item[1]/filename"/>
661 </xsl:attribute>
662 <xsl:attribute name="title">.dsc, use dget on this link to retrieve source package</xsl:attribute>
663 <img src="../common/save.png" alt="save" />
664 </xsl:element>
665 <xsl:choose>
666 <xsl:when test="starts-with($suite, 'security-')">
667 <xsl:element name="a">
668 <xsl:attribute name="href">
669 <xsl:text>http://packages.debian.org/source/</xsl:text>
670 <xsl:value-of select="str:replace($suite, 'security-', '')" />
671 <xsl:text>/</xsl:text>
672 <xsl:copy-of select="$package" />
673 </xsl:attribute>
674 <xsl:copy-of select="$version" />
675 </xsl:element>
676 </xsl:when>
677 <xsl:when test="str:replace($suite, '-backports', '') != $suite">
678 <xsl:copy-of select="$version" />
679 </xsl:when>
680 <xsl:when test="str:replace($suite, '-updates', '') != $suite">
681 <xsl:copy-of select="$version" />
682 </xsl:when>
683 <xsl:otherwise>
684 <a href="http://packages.debian.org/source/{$suite}/{$package}">
685 <xsl:copy-of select="$version" />
686 </a>
687 </xsl:otherwise>
688 </xsl:choose>
689 </xsl:when>
690 <xsl:otherwise>
691 <xsl:copy-of select="$version" />
692 </xsl:otherwise>
693 </xsl:choose>
694 </xsl:template>
695
696 <xsl:template name="more-info-marker">
697 <xsl:param name="href" />
698 <xsl:param name="title">more information are available on an external web page</xsl:param>
699 <a href="{$href}">
700 <img src="../common/external.png" title="{$title}" alt="..." />
701 </a>
702 </xsl:template>
703
704 <xsl:template name="available-versions">
705 <div class="block versions">
706 <a name="versions" />
707 <h2>versions
708 <xsl:call-template name="more-info-marker">
709 <xsl:with-param name="href">
710 <xsl:text>http://qa.debian.org/madison.php?package=</xsl:text>
711 <xsl:value-of select="$package" />
712 </xsl:with-param>
713 <xsl:with-param name="title">more versions can be listed by madison</xsl:with-param>
714 </xsl:call-template>
715 <xsl:text> </xsl:text>
716 <xsl:call-template name="more-info-marker">
717 <xsl:with-param name="href">http://snapshot.debian.org/package/<xsl:value-of select="package" />/</xsl:with-param>
718 <xsl:with-param name="title">old versions available from snapshot.debian.org</xsl:with-param>
719 </xsl:call-template>
720 <a class="dsc" href="{$mirror}/{$pooldir}">
721 <img src="../common/folder.png" alt="pool" title="pool directory" />
722 </a>
723 </h2>
724
725 <dl>
726 <xsl:if test="$hasoldstable">
727 <dt title="old stable release">oldstable</dt>
728 <dd>
729 <xsl:call-template name="output-version">
730 <xsl:with-param name="suite">oldstable</xsl:with-param>
731 </xsl:call-template>
732 </dd>
733 </xsl:if>
734 <xsl:if test="$hassecurity-oldstable">
735 <dt title="security updates for the old stable release">old-sec</dt>
736 <dd>
737 <xsl:call-template name="output-version">
738 <xsl:with-param name="suite">security-oldstable</xsl:with-param>
739 </xsl:call-template>
740 </dd>
741 </xsl:if>
742 <xsl:if test="$hasoldstable-updates">
743 <dt title="updates for the old stable release">old-upd</dt>
744 <dd>
745 <xsl:call-template name="output-version">
746 <xsl:with-param name="suite">oldstable-updates</xsl:with-param>
747 </xsl:call-template>
748 </dd>
749 </xsl:if>
750 <xsl:if test="$hasoldstable-backports">
751 <dt title="backports for the old stable release">old-bpo</dt>
752 <dd>
753 <xsl:call-template name="output-version">
754 <xsl:with-param name="suite">oldstable-backports</xsl:with-param>
755 </xsl:call-template>
756 </dd>
757 </xsl:if>
758 <xsl:if test="$hasstable">
759 <dt>stable</dt>
760 <dd>
761 <xsl:call-template name="output-version">
762 <xsl:with-param name="suite">stable</xsl:with-param>
763 </xsl:call-template>
764 </dd>
765 </xsl:if>
766 <xsl:if test="$hassecurity-stable">
767 <dt title="security updates for the stable release">stable-sec</dt>
768 <dd>
769 <xsl:call-template name="output-version">
770 <xsl:with-param name="suite">security-stable</xsl:with-param>
771 </xsl:call-template>
772 </dd>
773 </xsl:if>
774 <xsl:if test="$hasstable-updates">
775 <dt title="updates for the stable release">stable-upd</dt>
776 <dd>
777 <xsl:call-template name="output-version">
778 <xsl:with-param name="suite">stable-updates</xsl:with-param>
779 </xsl:call-template>
780 </dd>
781 </xsl:if>
782 <xsl:if test="$hasstable-proposed-updates">
783 <dt title="stable proposed updates">s-p-u</dt>
784 <dd>
785 <xsl:call-template name="output-version">
786 <xsl:with-param name="suite">stable-proposed-updates</xsl:with-param>
787 </xsl:call-template>
788 </dd>
789 </xsl:if>
790 <xsl:if test="$hasstable-backports">
791 <dt title="backports for the stable release">stable-bpo</dt>
792 <dd>
793 <xsl:call-template name="output-version">
794 <xsl:with-param name="suite">stable-backports</xsl:with-param>
795 </xsl:call-template>
796 </dd>
797 </xsl:if>
798 <xsl:if test="$hastesting">
799 <dt>testing</dt>
800 <dd>
801 <xsl:call-template name="output-version">
802 <xsl:with-param name="suite">testing</xsl:with-param>
803 </xsl:call-template>
804 </dd>
805 </xsl:if>
806 <xsl:if test="$hassecurity-testing">
807 <dt title="security updates for the testing release">testing-sec</dt>
808 <dd>
809 <xsl:call-template name="output-version">
810 <xsl:with-param name="suite">security-testing</xsl:with-param>
811 </xsl:call-template>
812 </dd>
813 </xsl:if>
814 <xsl:if test="$hastesting-proposed-updates">
815 <dt title="testing proposed updates">t-p-u</dt>
816 <dd>
817 <xsl:call-template name="output-version">
818 <xsl:with-param name="suite">testing-proposed-updates</xsl:with-param>
819 </xsl:call-template>
820 </dd>
821 </xsl:if>
822 <xsl:if test="$hasunstable">
823 <dt>unstable</dt>
824 <dd>
825 <xsl:call-template name="output-version">
826 <xsl:with-param name="suite">unstable</xsl:with-param>
827 </xsl:call-template>
828 </dd>
829 </xsl:if>
830 <xsl:if test="$hasexperimental">
831 <dt title="experimental release">exp</dt>
832 <dd>
833 <xsl:call-template name="output-version">
834 <xsl:with-param name="suite">experimental</xsl:with-param>
835 </xsl:call-template>
836 </dd>
837 </xsl:if>
838 <xsl:if test="$hasother and $other/@new_version">
839 <dt title="waiting in the NEW queue for FTP master review">
840 <a href="http://ftp-master.debian.org/new.html">NEW</a>
841 </dt>
842 <dd>
843 <xsl:value-of select="$other/@new_version" />
844 </dd>
845 </xsl:if>
846 </dl>
847 </div>
848 </xsl:template>
849
850 <xsl:template name="ubuntu">
851 <xsl:if test="$other/@ubuntu='yes'">
852 <div class="block ubuntu">
853 <a name="ubuntu" />
854 <h2>ubuntu
855 <img src="../common/ubuntu.png" alt="ubuntu" />
856 <xsl:text> </xsl:text>
857 <xsl:call-template name="more-info-marker">
858 <xsl:with-param name="href">https://wiki.ubuntu.com/Ubuntu/ForDebianDevelopers</xsl:with-param>
859 <xsl:with-param name="title">Information about Ubuntu for Debian Developers</xsl:with-param>
860 </xsl:call-template>
861 </h2>
862 <ul>
863 <li>
864 version: <a href="{$other/ubuntu/@url}"><xsl:value-of select="$other/ubuntu/@version"/></a>
865 </li>
866 <xsl:if test="$other/ubuntu/patch">
867 <li>
868 <a href="{$other/ubuntu/patch/@url}">patches for
869 <xsl:value-of select="$other/ubuntu/patch/@version"/></a>
870 </li>
871 </xsl:if>
872 <xsl:if test="$other/ubuntu/bugs">
873 <li>
874 <a href="{$other/ubuntu/bugs/@url}"><xsl:value-of select="$other/ubuntu/bugs/@count"/>
875 bugs</a>
876 <xsl:if test="$other/ubuntu/bugpatches">
877 (<a href="{$other/ubuntu/bugpatches/@url}"><xsl:value-of select="$other/ubuntu/bugpatches/@count"/>
878 patches</a>)
879 </xsl:if>
880 </li>
881 </xsl:if>
882 </ul>
883 </div>
884 </xsl:if>
885 </xsl:template>
886
887 <xsl:template name="output-patch-tracker-version">
888 <xsl:param name="suite" select="''" />
889 <xsl:param name="link" select="'yes'" />
890 <xsl:variable name="version">
891 <span class="srcversion" title="{$suite}">
892 <xsl:value-of select="document(concat('../base/', $dir, '/', $suite,
893 '.xml'))/source/version"/>
894 </span>
895 </xsl:variable>
896 <xsl:choose>
897 <xsl:when test="$link='yes'">
898 <a href="http://patch-tracker.debian.org/package/{$package}/{$version}">
899 <xsl:copy-of select="$version" />
900 </a>
901 </xsl:when>
902 <xsl:otherwise>
903 <xsl:copy-of select="$version" />
904 </xsl:otherwise>
905 </xsl:choose>
906 </xsl:template>
907
908 <xsl:template name="patch-tracker">
909 <div class="block patch-tracker">
910 <a name="patch-tracker" />
911 <h2>patch-tracker
912 <xsl:call-template name="more-info-marker">
913 <xsl:with-param name="href">http://patch-tracker.debian.org/package/<xsl:value-of select="package" /></xsl:with-param>
914 <xsl:with-param name="title">Link to patch tracker</xsl:with-param>
915 </xsl:call-template></h2>
916
917 <dl>
918 <xsl:if test="$hasoldstable">
919 <dt title="old stable release">oldstable</dt>
920 <dd>
921 <xsl:call-template name="output-patch-tracker-version">
922 <xsl:with-param name="suite">oldstable</xsl:with-param>
923 </xsl:call-template>
924 </dd>
925 </xsl:if>
926 <xsl:if test="$hasstable">
927 <dt>stable</dt>
928 <dd>
929 <xsl:call-template name="output-patch-tracker-version">
930 <xsl:with-param name="suite">stable</xsl:with-param>
931 </xsl:call-template>
932 </dd>
933 </xsl:if>
934 <xsl:if test="$hastesting">
935 <dt>testing</dt>
936 <dd>
937 <xsl:call-template name="output-patch-tracker-version">
938 <xsl:with-param name="suite">testing</xsl:with-param>
939 </xsl:call-template>
940 </dd>
941 </xsl:if>
942 <xsl:if test="$hasunstable">
943 <dt>unstable</dt>
944 <dd>
945 <xsl:call-template name="output-patch-tracker-version">
946 <xsl:with-param name="suite">unstable</xsl:with-param>
947 </xsl:call-template>
948 </dd>
949 </xsl:if>
950 <xsl:if test="$hasexperimental">
951 <dt title="experimental release">exp</dt>
952 <dd>
953 <xsl:call-template name="output-patch-tracker-version">
954 <xsl:with-param name="suite">experimental</xsl:with-param>
955 </xsl:call-template>
956 </dd>
957 </xsl:if>
958 </dl>
959 </div>
960 </xsl:template>
961
962 <xsl:template name="other-links">
963 <div class="block links">
964 <a name="links" />
965 <h2>links</h2>
966 <ul>
967 <xsl:if test="homepage">
968 <li><a title="upstream web homepage" href="{homepage}">homepage</a></li>
969 </xsl:if>
970 <li>
971 <xsl:element name="a">
972 <xsl:attribute name="href">
973 <xsl:text>http://packages.debian.org/changelogs/</xsl:text>
974 <xsl:value-of select="directory"/>
975 <xsl:text>/current/changelog</xsl:text>
976 </xsl:attribute>
977 <xsl:text>changelog</xsl:text>
978 </xsl:element>
979 /
980 <xsl:element name="a">
981 <xsl:attribute name="href">
982 <xsl:text>http://packages.debian.org/changelogs/</xsl:text>
983 <xsl:value-of select="directory"/>
984 <xsl:text>/current/copyright</xsl:text>
985 </xsl:attribute>
986 <xsl:text>copyright</xsl:text>
987 </xsl:element>
988 </li>
989 <xsl:if test="architecture!='all'">
990 <li>
991 <xsl:text>buildd: </xsl:text>
992 <a href="https://buildd.debian.org/status/package.php?p={$escaped-package}"
993 title="buildd.debian.org build logs">logs</a>
994 <xsl:text>, </xsl:text>
995 <xsl:if test="$hasexperimental">
996 <a href="https://buildd.debian.org/status/package.php?p={$escaped-package}&amp;suite=experimental"
997 title="experimental build logs">exp</a>
998 <xsl:text>, </xsl:text>
999 </xsl:if>
1000 <a href="http://buildd.debian-ports.org/status/package.php?p={$escaped-package}"
1001 title="debian ports build logs">ports</a>
1002 </li>
1003 </xsl:if>
1004 <xsl:if test="$other/@logcheck='yes'">
1005 <xsl:variable name="logcheck_url"><xsl:call-template name="mk_logcheck_url" /></xsl:variable>
1006 <li>
1007 <a title="report about issues spotted in buildd logs"
1008 href="{$logcheck_url}">build log checks</a>
1009 </li>
1010 </xsl:if>
1011 <xsl:if test="$hasother and $other/@piuparts='yes'">
1012 <li>
1013 <a title="report about errors found while stressing package installation"
1014 href="http://piuparts.debian.org/sid/source/{$hash}/{$package}.html">piuparts</a>
1015 </li>
1016 </xsl:if>
1017 <xsl:if test="($hasunstable and $other/debcheck/@unstable='yes')
1018 or ($hastesting and $other/debcheck/@testing='yes')
1019 or ($hasstable and $other/debcheck/@stable='yes')">
1020 <li>
1021 debcheck:
1022 <xsl:if test="$hasunstable">
1023 <xsl:text> </xsl:text>
1024 <a href="http://qa.debian.org/debcheck.php?dist=unstable&amp;package={$escaped-package}">unstable</a>
1025 </xsl:if>
1026 <xsl:if test="$hastesting">
1027 <xsl:text> </xsl:text>
1028 <a href="http://qa.debian.org/debcheck.php?dist=testing&amp;package={$escaped-package}">testing</a>
1029 </xsl:if>
1030 <xsl:if test="$hasstable">
1031 <xsl:text> </xsl:text>
1032 <a href="http://qa.debian.org/debcheck.php?dist=stable&amp;package={$escaped-package}">stable</a>
1033 </xsl:if>
1034 </li>
1035 </xsl:if>
1036 <xsl:if test="$other/@lintian='yes'">
1037 <xsl:variable name="lintian_url"><xsl:call-template name="mk_lintian_url" /></xsl:variable>
1038 <li>
1039 <a title="report about packaging issues spotted by lintian"
1040 href="{$lintian_url}">lintian</a>
1041 <!-- <xsl:if test="$lin_errs + $lin_warns > 0"> -->
1042 <!-- <xsl:text> </xsl:text> -->
1043 <!-- <small><span title="(errors, warnings)">(<span id="lintian_errors"><xsl:value-of select="$lin_errs" /></span>, -->
1044 <!-- <span id="lintian_warnings"><xsl:value-of select="$lin_warns" /></span>)</span></small> -->
1045 <!-- </xsl:if> -->
1046 </li>
1047 </xsl:if>
1048 <li>
1049 <a title="package popularity"
1050 href="http://qa.debian.org/popcon.php?package={$escaped-package}">popcon</a>
1051 </li>
1052 <xsl:if test="$other/@svnbuildstat='yes'">
1053 <li>
1054 <a href="http://svnbuildstat.debian.net/packages/info/{$escaped-package}">Svnbuildstat</a>
1055 </li>
1056 </xsl:if>
1057 <xsl:if test="$other/i18n/@href">
1058 <li>
1059 <a title="translation status"
1060 href="{$other/i18n/@href}">l10n</a>
1061 <small>
1062 (<span title="completeness of Debian string translation">
1063 <xsl:value-of select="$other/i18n/@deb" />
1064 </span>,
1065 <span title="completeness of non-Debian string translation">
1066 <xsl:value-of select="$other/i18n/@nondeb" />
1067 </span>)
1068 </small>
1069 </li>
1070 </xsl:if>
1071 <xsl:if test="$other/@fonts='yes'">
1072 <li>
1073 <a title="fonts review" href="{$other/fonts/@href}">fonts</a>
1074 </li>
1075 </xsl:if>
1076 <li>
1077 <xsl:choose>
1078 <xsl:when test="count(binary/item) &lt; 2">
1079 <xsl:variable name="binary-package" select="binary[1]/item"/>
1080 <xsl:variable name="escaped-binary-package">
1081 <xsl:call-template name="escape-name">
1082 <xsl:with-param name="text"><xsl:value-of select="binary[1]/item"/></xsl:with-param>
1083 </xsl:call-template>
1084 </xsl:variable>
1085 <a title="edit {$binary-package} debtags" href="http://debtags.alioth.debian.org/edit.html?pkg={$escaped-binary-package}">debtags</a>
1086 </xsl:when>
1087 <xsl:otherwise>
1088 <xsl:variable name="escaped-email">
1089 <xsl:call-template name="escape-name">
1090 <xsl:with-param name="text"><xsl:value-of select="maintainer/email"/></xsl:with-param>
1091 </xsl:call-template>
1092 </xsl:variable>
1093 <xsl:variable name="maintainer-name"><xsl:value-of select="maintainer/name"/></xsl:variable>
1094 <a title="edit all debtags for {$maintainer-name}" href="http://debtags.alioth.debian.org/todo.html?maint={$escaped-email}#{$escaped-package}">debtags</a>
1095 (<xsl:for-each select="binary/item">
1096 <xsl:sort select="text()"/>
1097 <xsl:variable name="binary-package" select="text()"/>
1098 <xsl:variable name="escaped-binary-package">
1099 <xsl:call-template name="escape-name">
1100 <xsl:with-param name="text"><xsl:value-of select="text()"/></xsl:with-param>
1101 </xsl:call-template>
1102 </xsl:variable>
1103 <a title="edit {$binary-package} debtags" href="http://debtags.alioth.debian.org/edit.html?pkg={$escaped-binary-package}"><xsl:value-of select="position()"/></a>
1104 <xsl:if test="not(position() = last())">, </xsl:if>
1105 </xsl:for-each>)
1106 </xsl:otherwise>
1107 </xsl:choose>
1108 </li>
1109 </ul>
1110 </div>
1111 </xsl:template>
1112
1113 <xsl:template name="todo-list">
1114 <xsl:variable name="todo">
1115 <xsl:call-template name="issue-security" />
1116 <xsl:call-template name="issue-nmu" />
1117 <xsl:call-template name="issue-lintian" />
1118 <xsl:call-template name="issue-logcheck" />
1119 <xsl:call-template name="issue-mentors-pending" />
1120 <xsl:call-template name="issue-comaintenance" />
1121 <xsl:call-template name="issue-outdate-stdver" />
1122 <xsl:call-template name="issue-new-upstream" />
1123 <xsl:call-template name="issue-patches" />
1124 <xsl:call-template name="issue-l10n" />
1125 <xsl:if test="$hasother">
1126 <xsl:for-each select="$other/todo/item">
1127 <xsl:call-template name="outputitem" />
1128 </xsl:for-each>
1129 </xsl:if>
1130 </xsl:variable>
1131
1132 <xsl:if test="count($todo)>0 and string($todo)!=''">
1133 <div class="block todo">
1134 <a name="todo" />
1135 <h2>todo</h2>
1136 <ul>
1137 <xsl:copy-of select="$todo" />
1138 </ul>
1139 </div>
1140 </xsl:if>
1141 </xsl:template>
1142
1143 <xsl:template name="problems">
1144 <xsl:variable name="problems">
1145 <xsl:call-template name="issue-testing-excuses" />
1146 <xsl:call-template name="issue-piuparts" />
1147 <xsl:call-template name="issue-ancient-stdver" />
1148 <xsl:call-template name="issue-item-dead-package" />
1149 <xsl:call-template name="issue-item-override-disparity" />
1150 <xsl:call-template name="issue-item-help-bugs" />
1151 <xsl:call-template name="issue-item-wnpp" />
1152 <!-- <xsl:call-template name="issue-item-watch-failure" /> -->
1153 <xsl:call-template name="issue-item-dehs-failure" />
1154 <xsl:if test="$hasother">
1155 <xsl:for-each select="$other/problems/item">
1156 <xsl:call-template name="outputitem"/>
1157 </xsl:for-each>
1158 </xsl:if>
1159 </xsl:variable>
1160
1161 <xsl:if test="count($problems)>0 and string($problems)!=''">
1162 <div class="block problems">
1163 <a name="problems" />
1164 <h2>problems</h2>
1165 <ul>
1166 <xsl:copy-of select="$problems" />
1167 </ul>
1168 </div>
1169 </xsl:if>
1170 </xsl:template>
1171
1172 <xsl:template name="testing-status">
1173 <xsl:if test="$hasexcuse or $other/@transitions='yes'">
1174 <div class="block testing">
1175 <a name="testing" />
1176 <h2>testing migration</h2>
1177 <xsl:if test="$other/@transitions='yes'">
1178 <xsl:variable name="translist">
1179 <xsl:for-each select="$other/transitions/transition">
1180 <xsl:value-of select="@name" />
1181 <xsl:if test="position() != last()"> <xsl:text> </xsl:text>
1182 </xsl:if>
1183 </xsl:for-each>
1184 </xsl:variable>
1185 <xsl:variable name="transno"
1186 select="count($other/transitions/transition)" />
1187 <div class="warning">
1188 <!-- XXX unappropriate <ul>, just to make the text looks like other
1189 boxes, should be fixed on the CSS side (getting rid of <ul>) -->
1190 <p>This package is part of <em><xsl:value-of select="$transno" /> ongoing
1191 testing transition<xsl:if test="$transno != '1'">s</xsl:if></em>
1192 (namely: <tt><xsl:value-of select="$translist" /></tt>). For
1193 more information see the
1194 <a href="http://ftp-master.debian.org/transitions.yaml">transition
1195 status file</a>.<br />
1196 <em>Uploads to unstable will be rejected</em> while
1197 transitions are ongoing; you might want to upload to
1198 experimental in the meantime, or
1199 contact <tt><a href="mailto:debian-release@lists.debian.org">debian-release</a></tt>
1200 if an upload is really necessary.
1201 </p>
1202 </div>
1203 </xsl:if>
1204 <xsl:if test="$hasexcuse">
1205 <a title="reasons why the package is not moving to testing"
1206 href="http://qa.debian.org/excuses.php?package={$escaped-package}">excuses</a>:
1207 <ul class="testing-excuses">
1208 <xsl:for-each select="document(concat('../base/', $dir, '/excuse.xml'))/excuse/item">
1209 <xsl:call-template name="outputitem"/>
1210 </xsl:for-each>
1211 </ul>
1212 </xsl:if>
1213 </div>
1214 </xsl:if>
1215 </xsl:template>
1216
1217 <xsl:template name="static-info">
1218 <xsl:call-template name="output-static">
1219 <xsl:with-param name="static" select="$static" />
1220 </xsl:call-template>
1221 </xsl:template>
1222
1223 <xsl:template name="latest-news">
1224 <xsl:call-template name="output-news">
1225 <xsl:with-param name="news" select="$news" />
1226 </xsl:call-template>
1227 </xsl:template>
1228
1229 <xsl:variable name="static">
1230 <xsl:if test="$hasnews">
1231 <xsl:for-each select="document(concat('../base/', $dir, '/news.xml'))/news/static/item">
1232 <xsl:call-template name="outputitem"/>
1233 </xsl:for-each>
1234 </xsl:if>
1235 </xsl:variable>
1236
1237 <xsl:variable name="news">
1238 <xsl:if test="$hasnews">
1239 <xsl:for-each select="document(concat('../base/', $dir, '/news.xml'))/news/news/item">
1240 <xsl:call-template name="outputitem"/>
1241 </xsl:for-each>
1242 </xsl:if>
1243 </xsl:variable>
1244
1245 <!-- All the work is done in a single template -->
1246 <xsl:template match="source">
1247
1248 <!-- Start of html -->
1249 <html>
1250 <head>
1251 <meta name="ROBOTS" content="NOFOLLOW"/>
1252 <link type="text/css" title="User selected" rel="stylesheet" href="../common/default.css"/>
1253 <link type="text/css" title="Official" rel="alternate stylesheet" href="../common/revamp.css"/>
1254 <link type="text/css" title="Legacy PTS" rel="alternate stylesheet" href="../common/pts.css"/>
1255 <link type="text/css" title="Compact rendering" rel="alternate stylesheet" href="../common/compact.css"/>
1256 <script type="text/javascript" src="../common/pts.js"></script>
1257 <xsl:if test="count($news)>0 and string($news)!=''">
1258 <link rel="alternate" type="application/rss+xml" title="RSS"
1259 href="{$package}/news.rss20.xml" />
1260 </xsl:if>
1261 <title>Debian Package Tracking System -
1262 <xsl:value-of select="$package"/></title>
1263 </head>
1264 <body onload="javascript:onLoad();">
1265 <div class="quickform" style="float: right;">
1266 <form title="jump to the PTS page of another source package"
1267 method="get" action="/common/index.html">
1268 <p>
1269 <input type="text" size="14" name="src" value=""/>
1270 <input type="submit" value="jump to" />
1271 </p>
1272 </form>
1273 </div>
1274
1275 <h1>
1276 <xsl:value-of select="$package"/><br />
1277 <small>source package</small>
1278 </h1>
1279
1280 <div id="body">
1281 <xsl:choose>
1282 <xsl:when test="$removed='yes'">
1283 <div class="block removed">
1284 <p>This package is not part of any Debian
1285 distribution. Thus you won't find much information
1286 here. The package is either very new and hasn't
1287 appeared on mirrors yet, or it's an old package that
1288 eventually got removed. The old news are kept for
1289 historic purpose only.</p>
1290 <xsl:call-template name="static-info" />
1291 <xsl:call-template name="latest-news" />
1292 </div>
1293 </xsl:when>
1294 <xsl:otherwise> <!-- non removed package -->
1295 <div class="left maincol">
1296 <xsl:call-template name="general-information" />
1297 <xsl:call-template name="available-versions" />
1298 <xsl:call-template name="binary-packages" />
1299 </div>
1300 <div class="center maincol">
1301 <xsl:call-template name="todo-list" />
1302 <xsl:call-template name="problems" />
1303 <xsl:call-template name="testing-status" />
1304 <xsl:call-template name="static-info" />
1305 <xsl:call-template name="latest-news" />
1306 </div>
1307 <div class="right maincol">
1308 <xsl:call-template name="bugs-count" />
1309 <xsl:call-template name="other-links" />
1310 <xsl:call-template name="ubuntu" />
1311 <xsl:call-template name="patch-tracker" />
1312 </div>
1313 </xsl:otherwise>
1314 </xsl:choose>
1315
1316 <hr/>
1317 <div class="footer">
1318 <table width="100%">
1319 <tr>
1320 <td>
1321 <!--
1322 <div class="quickform">
1323 <form id="csspref-form" method="get"
1324 action="/common/set-csspref.php">
1325 <p>
1326 change skin:
1327 <select name="csspref" onchange="javascript:onChangeStyle();">
1328 <option value="revamp.css">default</option>
1329 <option value="compact.css">compact</option>
1330 <option value="pts.css">legacy</option>
1331 </select>
1332 </p>
1333 </form>
1334 </div>
1335 -->
1336 <div class="quickform">
1337 <xsl:call-template name="pts-subscription" />
1338 </div>
1339 </td>
1340 <td>
1341 <p>
1342 <em><a href="http://www.debian.org">Debian</a>
1343 Package Tracking System</em> - Copyright ©
1344 2002-2009 Raphaël Hertzog, Stefano Zacchiroli and
1345 others.<br/> Report problems to the
1346 <a href="http://bugs.debian.org/qa.debian.org"><tt>qa.debian.org</tt>
1347 pseudopackage</a> in the <a href="http://bugs.debian.org">Debian
1348 <acronym title="Bug Tracking System">BTS</acronym></a>.<br/>
1349 <a href="svn://svn.debian.org/svn/qa/trunk/pts">Checkout SVN repository</a> |
1350 <a href="http://anonscm.debian.org/viewvc/qa/trunk/pts/">Browse SVN repository</a><br/>
1351 Last modified: <xsl:value-of select="$date"/>.
1352 </p>
1353 </td>
1354 <td>
1355 <a href="http://validator.w3.org/check?uri=referer">
1356 <img
1357 src="http://www.w3.org/Icons/valid-xhtml10-blue"
1358 alt="Valid XHTML 1.0 Strict" height="31" width="88" />
1359 </a>
1360 </td>
1361 </tr>
1362 </table>
1363 </div>
1364 </div>
1365 </body>
1366 </html>
1367 </xsl:template>
1368
1369 </xsl:stylesheet>

Properties

Name Value
svn:eol-style native
svn:keywords Author Date Id Revision
  ViewVC Help
Powered by ViewVC 1.1.5