(root)/users/lolando/sgeps/trunk : /sgeps (revision 15)

#! /usr/bin/perl -w

#

# A simple GnuPG-encrypted password store

#

# Allows to store key/{login,password,notes} pairs in a GPG-encrypted file

#

# Copyright © 2009, Roland Mas <lolando@debian.org>

# Copyright © 2010, Ben Voui <intrigeri@boum.org>

# 

# This program is free software; you can redistribute it and/or modify

# it under the terms of the GNU General Public License as published by

# the Free Software Foundation; either version 2 of the License, or

# (at your option) any later version.

#

# Usage: sgeps --create	       	   	    to create the store

#        sgeps --add <key>       	    to add a key/value to the store

#        sgeps --read <key>                 to read all data of a key from the store

#        sgeps --copy <key>                 to copy the login and password of a key to the X clipboard

#        sgeps --copy --login <key>         to copy the login of a key to the X clipboard

#        sgeps --copy --password <key>      to copy the password of a key to the X clipboard

#        sgeps --delete <key>	       	    to delete a key from the store

#        sgeps --list	       	   	    to list existing keys

#        sgeps --search <pattern>           to list existing keys matching the pattern

#        sgeps --add --overwrite <key>      to replace a key/value

#        sgeps --add --batch <key>   	    to add a key/value to the store with no interactive terminal

#        sgeps --edit <key>                 to edit the data for a key

# 

# Sample config file, to be stored in ~/.config/sgeps.conf (unless

# overridden with --config=.../foo.conf):

# ,----

# | store = ~/s1kr3t/sgeps.gpg

# | keyid = 0x12345678

# `----

#

# Non-Perl dependencies: GnuPG, xclip.

#

# TODO:

# - add status messages for --copy, to ease frontends development.

use strict ;

use Storable qw/ nfreeze thaw / ;

use File::Temp qw/ tempdir / ;

use Getopt::Long ;

use Config::Simple ;

use Term::ReadLine;

use vars qw/ %database %flags $config_file %config / ;

$config_file = "$ENV{HOME}/.config/sgeps.conf" ;

my $result = GetOptions ("read"      => \$flags{read},

			 "copy"      => \$flags{copy},

			 "login"     => \$flags{login},

			 "password"  => \$flags{password},

			 "both"      => \$flags{both},

			 "add"	     => \$flags{add},

			 "delete"    => \$flags{delete},

			 "overwrite" => \$flags{overwrite},

			 "batch"     => \$flags{batch},

			 "edit"	     => \$flags{edit},

			 "list"	     => \$flags{list},

			 "search"    => \$flags{search},

			 "create"    => \$flags{create},

			 "xclip"     => \$flags{xclip},

			 "config=s"  => \$config_file,

    ) ;

$config_file = glob $config_file ;

tie %config, "Config::Simple", $config_file or die Config::Simple->error() ;

$config{store} = glob $config{store} ;

SWITCH: {

    ($flags{read} || $flags{copy}) && do {

	my $kw = $ARGV[0] ;

	die "No key specified" unless (defined $kw and $kw ne '') ;

	&readfile ;

        die "No defined value for $kw" 	unless defined $database{$kw} ;

        my $v = $database{$kw} ;

        # update the entry to the new format

        if (! ref($v)) {

            $database{$kw} = {

                login    => $kw,

                password => $v,

                notes    => '',

            } ;

            &writefile ;

            $v = $database{$kw} ;

        }

        if ($flags{read} && ! $flags{xclip}) {

            print "login: "    . $v->{login} . "\n" ;

            print "password: " . $v->{password} . "\n" ;

            print "notes: "    . $v->{notes}    . "\n" ;

        }

        elsif ($flags{read} && $flags{xclip}) {

            &copyandwait($v->{password}) ;

            &emptyclipboard ;

        }

        elsif ($flags{copy}) {

            if ($flags{login}) {

                &copyandwait($v->{login}) ;

                &emptyclipboard ;

            }

            elsif ($flags{password}) {

                &copyandwait($v->{password}) ;

                &emptyclipboard ;

            }

            else {

                &copyandwait($v->{login}) ;

                &emptyclipboard ;

                &copyandwait($v->{password}) ;

                &emptyclipboard ;

            }

        }

	last SWITCH ;

    } ;

    ($flags{list} || $flags{search}) && do {

	my $pattern = $ARGV[0] ;

	if (defined $flags{search}) { 

	    die "No pattern specified" unless (defined $pattern and $pattern ne '') ;

	}

	&readfile ;

	print "Defined keys" ;

	print " (looking for pattern $pattern)" if (defined $flags{search}) ;

	print ":\n" ;

	foreach my $key (sort {$a cmp $b} keys %database) {

	    if (defined $flags{search}) {

		print "$key\n" if ($key =~ m/$pattern/) ;

	    } else {

		print "$key\n" ;

	    }

	}

	last SWITCH ;

    } ;

    ($flags{add} || $flags{edit}) && do {

	my $kw = $ARGV[0] ;

	die "No key specified" unless (defined $kw and $kw ne '') ;

	&readfile ;

	if (defined ($database{$kw}) && !$flags{overwrite} && !$flags{edit}) {

	    die "Value already defined for $kw, use --overwrite or --edit" ;

	}

        my %defaults = (

            login    => '',

            password => '',

            notes    => '',

        );

        if ($flags{add}) {

            $defaults{login} = $kw ;

        }

        elsif ($flags{edit}) {

            %defaults = %{$database{$kw}}

        }

        $database{$kw} = promptdata($kw, %defaults) ;

	&writefile ;

	last SWITCH ;

    } ;

    $flags{delete} && do {

	my $kw = $ARGV[0] ;

	die "No key specified" unless (defined $kw and $kw ne '') ;

	print "Are you sure? (y/N) ";

	my $val = <STDIN>;

	chomp $val;

	last SWITCH if $val ne 'y';

	&readfile ;

	print "Removing $kw from the store\n" ;

	delete $database{$kw};

	&writefile ;

	last SWITCH ;

    } ;

    $flags{create} && do {

	if (-e $config{store}) {

	    die "Store already exists" ;

	}

	%database = () ;

	&writefile ;

	last SWITCH ;

    } ;

}

exit 0 ;

sub readfile () {

    my $clear = qx! gpg -q -d $config{store} ! ;

    if ($? != 0) {

	die "Error while opening store" ;

    }

    %database = %{thaw $clear} ;

}

sub writefile () {

    my $clear = nfreeze \%database ;

    my $tmpdir = tempdir "$config{store}.XXXXXX" ;

    my $tmp = "$tmpdir/store" ;

    open W, "| gpg --encrypt --armor --recipient $config{keyid} --output $tmp 2> /dev/null"

        or die "Error opening a pipe to gpg" ;

    print W $clear or die "Error writing to the gpg pipe" ;

    close W or die "Error closing pipe to gpg" ;

    rename $tmp, $config{store} or die "Error moving temporary file to " . $config{store} ;

    rmdir $tmpdir ;

}

# copy passed string to the X clipboard, then wait for it to have been pasted,

# then empty the clipboard

sub copyandwait () {

    my $string = shift ;

    # bug in xclip: removing -verbose breaks -loops functionality

    open XCLIP, "| xclip -loops 1 -verbose >/dev/null 2>&1"

        or die "Error opening pipe to xclip" ;

    print XCLIP $string or die "Error copying data to X clipboard" ;

    close XCLIP or die "Error closing pipe to xclip" ;

    &emptyclipboard;

}

sub emptyclipboard () {

    open XCLIP, "| xclip" or die "Error opening pipe to xclip" ;

    print XCLIP "" or die "Error copying data to X clipboard" ;

    close XCLIP or die "Error closing pipe to xclip" ;

}

sub promptdata {

    my $key = shift ;

    my %default = @_ ;

    if ($flags{batch}) {

        my ($login, $password, $notes) = (<STDIN>, <STDIN>, <STDIN>);

        chomp ($login, $password, $notes);

        return {

            login    => $login,

            password => $password,

            notes    => $notes,

        } ;

    }

    else {

        my $term = Term::ReadLine->new('sgeps') ;

        return {

            login    => $term->readline("Login: ",    $default{login}),

            password => $term->readline("Password: ", $default{password}),

            notes    => $term->readline("Notes: ",    $default{notes}),

        } ;

    }

}