po: Update Simplified Chinese programs translation
[dpkg/dpkg.git] / scripts / Dpkg / Shlibs / SymbolFile.pm
1 # Copyright © 2007 Raphaël Hertzog <hertzog@debian.org>
2 # Copyright © 2009-2010 Modestas Vainius <modax@debian.org>
3 #
4 # This program is free software; you can redistribute it and/or modify
5 # it under the terms of the GNU General Public License as published by
6 # the Free Software Foundation; either version 2 of the License, or
7 # (at your option) any later version.
8 #
9 # This program is distributed in the hope that it will be useful,
10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
12 # GNU General Public License for more details.
13 #
14 # You should have received a copy of the GNU General Public License
15 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
16
17 package Dpkg::Shlibs::SymbolFile;
18
19 use strict;
20 use warnings;
21
22 our $VERSION = '0.01';
23
24 use Dpkg::Gettext;
25 use Dpkg::ErrorHandling;
26 use Dpkg::Version;
27 use Dpkg::Control::Fields;
28 use Dpkg::Shlibs::Symbol;
29 use Dpkg::Arch qw(get_host_arch);
30
31 use parent qw(Dpkg::Interface::Storable);
32
33 my %blacklist = (
34     __bss_end__ => 1,                   # arm
35     __bss_end => 1,                     # arm
36     _bss_end__ => 1,                    # arm
37     __bss_start => 1,                   # ALL
38     __bss_start__ => 1,                 # arm
39     __data_start => 1,                  # arm
40     __do_global_ctors_aux => 1,         # ia64
41     __do_global_dtors_aux => 1,         # ia64
42     __do_jv_register_classes => 1,      # ia64
43     _DYNAMIC => 1,                      # ALL
44     _edata => 1,                        # ALL
45     _end => 1,                          # ALL
46     __end__ => 1,                       # arm
47     __exidx_end => 1,                   # armel
48     __exidx_start => 1,                 # armel
49     _fbss => 1,                         # mips, mipsel
50     _fdata => 1,                        # mips, mipsel
51     _fini => 1,                         # ALL
52     _ftext => 1,                        # mips, mipsel
53     _GLOBAL_OFFSET_TABLE_ => 1,         # hppa, mips, mipsel
54     __gmon_start__ => 1,                # hppa
55     __gnu_local_gp => 1,                # mips, mipsel
56     _gp => 1,                           # mips, mipsel
57     _init => 1,                         # ALL
58     _PROCEDURE_LINKAGE_TABLE_ => 1,     # sparc, alpha
59     _SDA2_BASE_ => 1,                   # powerpc
60     _SDA_BASE_ => 1,                    # powerpc
61 );
62
63 for my $i (14 .. 31) {
64     # Many powerpc specific symbols
65     $blacklist{"_restfpr_$i"} = 1;
66     $blacklist{"_restfpr_$i\_x"} = 1;
67     $blacklist{"_restgpr_$i"} = 1;
68     $blacklist{"_restgpr_$i\_x"} = 1;
69     $blacklist{"_savefpr_$i"} = 1;
70     $blacklist{"_savegpr_$i"} = 1;
71 }
72
73 sub symbol_is_blacklisted {
74     my ($symbol, $include_groups) = @_;
75
76     return 1 if exists $blacklist{$symbol};
77
78     # The ARM Embedded ABI spec states symbols under this namespace as
79     # possibly appearing in output objects.
80     return 1 if not ${$include_groups}{aeabi} and $symbol =~ /^__aeabi_/;
81
82     # The GNU implementation of the OpenMP spec, specifies symbols under
83     # this namespace as possibly appearing in output objects.
84     return 1 if not ${$include_groups}{gomp}
85                 and $symbol =~ /^\.gomp_critical_user_/;
86
87     return 0;
88 }
89
90 sub new {
91     my ($this, %opts) = @_;
92     my $class = ref($this) || $this;
93     my $self = \%opts;
94     bless $self, $class;
95     $self->{arch} //= get_host_arch();
96     $self->clear();
97     if (exists $self->{file}) {
98         $self->load($self->{file}) if -e $self->{file};
99     }
100     return $self;
101 }
102
103 sub get_arch {
104     my ($self) = @_;
105     return $self->{arch};
106 }
107
108 sub clear {
109     my ($self) = @_;
110     $self->{objects} = {};
111 }
112
113 sub clear_except {
114     my ($self, @ids) = @_;
115     my %has;
116     $has{$_} = 1 foreach (@ids);
117     foreach my $objid (keys %{$self->{objects}}) {
118         delete $self->{objects}{$objid} unless exists $has{$objid};
119     }
120 }
121
122 sub get_sonames {
123     my ($self) = @_;
124     return keys %{$self->{objects}};
125 }
126
127 sub get_symbols {
128     my ($self, $soname) = @_;
129     if (defined $soname) {
130         my $obj = $self->get_object($soname);
131         return (defined $obj) ? values %{$obj->{syms}} : ();
132     } else {
133         my @syms;
134         foreach my $soname ($self->get_sonames()) {
135             push @syms, $self->get_symbols($soname);
136         }
137         return @syms;
138     }
139 }
140
141 sub get_patterns {
142     my ($self, $soname) = @_;
143     my @patterns;
144     if (defined $soname) {
145         my $obj = $self->get_object($soname);
146         foreach my $alias (values %{$obj->{patterns}{aliases}}) {
147             push @patterns, values %$alias;
148         }
149         return (@patterns, @{$obj->{patterns}{generic}});
150     } else {
151         foreach my $soname ($self->get_sonames()) {
152             push @patterns, $self->get_patterns($soname);
153         }
154         return @patterns;
155     }
156 }
157
158 # Create a symbol from the supplied string specification.
159 sub create_symbol {
160     my ($self, $spec, %opts) = @_;
161     my $symbol = (exists $opts{base}) ? $opts{base} :
162         Dpkg::Shlibs::Symbol->new();
163
164     my $ret = $opts{dummy} ? $symbol->parse_symbolspec($spec, default_minver => 0) :
165         $symbol->parse_symbolspec($spec);
166     if ($ret) {
167         $symbol->initialize(arch => $self->get_arch());
168         return $symbol;
169     }
170     return;
171 }
172
173 sub add_symbol {
174     my ($self, $symbol, $soname) = @_;
175     my $object = $self->get_object($soname);
176
177     if ($symbol->is_pattern()) {
178         if (my $alias_type = $symbol->get_alias_type()) {
179             $object->{patterns}{aliases}{$alias_type} //= {};
180             # Alias hash for matching.
181             my $aliases = $object->{patterns}{aliases}{$alias_type};
182             $aliases->{$symbol->get_symbolname()} = $symbol;
183         } else {
184             # Otherwise assume this is a generic sequential pattern. This
185             # should be always safe.
186             push @{$object->{patterns}{generic}}, $symbol;
187         }
188         return 'pattern';
189     } else {
190         # invalidate the minimum version cache
191         $object->{minver_cache} = [];
192         $object->{syms}{$symbol->get_symbolname()} = $symbol;
193         return 'sym';
194     }
195 }
196
197 sub _new_symbol {
198     my $base = shift || 'Dpkg::Shlibs::Symbol';
199     return (ref $base) ? $base->clone(@_) : $base->new(@_);
200 }
201
202 # Parameter seen is only used for recursive calls
203 sub parse {
204     my ($self, $fh, $file, $seen, $obj_ref, $base_symbol) = @_;
205
206     if (defined($seen)) {
207         return if exists $seen->{$file}; # Avoid include loops
208     } else {
209         $self->{file} = $file;
210         $seen = {};
211     }
212     $seen->{$file} = 1;
213
214     if (not ref($obj_ref)) { # Init ref to name of current object/lib
215         $$obj_ref = undef;
216     }
217
218     while (<$fh>) {
219         chomp;
220
221         if (/^(?:\s+|#(?:DEPRECATED|MISSING): ([^#]+)#\s*)(.*)/) {
222             if (not defined ($$obj_ref)) {
223                 error(_g('symbol information must be preceded by a header (file %s, line %s)'), $file, $.);
224             }
225             # Symbol specification
226             my $deprecated = ($1) ? $1 : 0;
227             my $sym = _new_symbol($base_symbol, deprecated => $deprecated);
228             if ($self->create_symbol($2, base => $sym)) {
229                 $self->add_symbol($sym, $$obj_ref);
230             } else {
231                 warning(_g('failed to parse line in %s: %s'), $file, $_);
232             }
233         } elsif (/^(\(.*\))?#include\s+"([^"]+)"/) {
234             my $tagspec = $1;
235             my $filename = $2;
236             my $dir = $file;
237             my $new_base_symbol;
238             if (defined $tagspec) {
239                 $new_base_symbol = _new_symbol($base_symbol);
240                 $new_base_symbol->parse_tagspec($tagspec);
241             }
242             $dir =~ s{[^/]+$}{}; # Strip filename
243             $self->load("$dir$filename", $seen, $obj_ref, $new_base_symbol);
244         } elsif (/^#|^$/) {
245             # Skip possible comments and empty lines
246         } elsif (/^\|\s*(.*)$/) {
247             # Alternative dependency template
248             push @{$self->{objects}{$$obj_ref}{deps}}, "$1";
249         } elsif (/^\*\s*([^:]+):\s*(.*\S)\s*$/) {
250             # Add meta-fields
251             $self->{objects}{$$obj_ref}{fields}{field_capitalize($1)} = $2;
252         } elsif (/^(\S+)\s+(.*)$/) {
253             # New object and dependency template
254             $$obj_ref = $1;
255             if (exists $self->{objects}{$$obj_ref}) {
256                 # Update/override infos only
257                 $self->{objects}{$$obj_ref}{deps} = [ "$2" ];
258             } else {
259                 # Create a new object
260                 $self->create_object($$obj_ref, "$2");
261             }
262         } else {
263             warning(_g('failed to parse a line in %s: %s'), $file, $_);
264         }
265     }
266     delete $seen->{$file};
267 }
268
269 # Beware: we reuse the data structure of the provided symfile so make
270 # sure to not modify them after having called this function
271 sub merge_object_from_symfile {
272     my ($self, $src, $objid) = @_;
273     if (not $self->has_object($objid)) {
274         $self->{objects}{$objid} = $src->get_object($objid);
275     } else {
276         warning(_g('tried to merge the same object (%s) twice in a symfile'), $objid);
277     }
278 }
279
280 sub output {
281     my ($self, $fh, %opts) = @_;
282     $opts{template_mode} //= 0;
283     $opts{with_deprecated} //= 1;
284     $opts{with_pattern_matches} //= 0;
285     my $res = '';
286     foreach my $soname (sort $self->get_sonames()) {
287         my @deps = $self->get_dependencies($soname);
288         my $dep_first = shift @deps;
289         $dep_first =~ s/#PACKAGE#/$opts{package}/g if exists $opts{package};
290         print { $fh } "$soname $dep_first\n" if defined $fh;
291         $res .= "$soname $dep_first\n" if defined wantarray;
292
293         foreach my $dep_next (@deps) {
294             $dep_next =~ s/#PACKAGE#/$opts{package}/g if exists $opts{package};
295             print { $fh } "| $dep_next\n" if defined $fh;
296             $res .= "| $dep_next\n" if defined wantarray;
297         }
298         my $f = $self->{objects}{$soname}{fields};
299         foreach my $field (sort keys %{$f}) {
300             my $value = $f->{$field};
301             $value =~ s/#PACKAGE#/$opts{package}/g if exists $opts{package};
302             print { $fh } "* $field: $value\n" if defined $fh;
303             $res .= "* $field: $value\n" if defined wantarray;
304         }
305
306         my @symbols;
307         if ($opts{template_mode}) {
308             # Exclude symbols matching a pattern, but include patterns themselves
309             @symbols = grep { not $_->get_pattern() } $self->get_symbols($soname);
310             push @symbols, $self->get_patterns($soname);
311         } else {
312             @symbols = $self->get_symbols($soname);
313         }
314         foreach my $sym (sort { $a->get_symboltempl() cmp
315                                 $b->get_symboltempl() } @symbols) {
316             next if $sym->{deprecated} and not $opts{with_deprecated};
317             # Do not dump symbols from foreign arch unless dumping a template.
318             next if not $opts{template_mode} and
319                     not $sym->arch_is_concerned($self->get_arch());
320             # Dump symbol specification. Dump symbol tags only in template mode.
321             print { $fh } $sym->get_symbolspec($opts{template_mode}), "\n" if defined $fh;
322             $res .= $sym->get_symbolspec($opts{template_mode}) . "\n" if defined wantarray;
323             # Dump pattern matches as comments (if requested)
324             if ($opts{with_pattern_matches} && $sym->is_pattern()) {
325                 for my $match (sort { $a->get_symboltempl() cmp
326                                       $b->get_symboltempl() } $sym->get_pattern_matches())
327                 {
328                     print { $fh } '#MATCH:', $match->get_symbolspec(0), "\n" if defined $fh;
329                     $res .= '#MATCH:' . $match->get_symbolspec(0) . "\n" if defined wantarray;
330                 }
331             }
332         }
333     }
334     return $res;
335 }
336
337 # Tries to match a symbol name and/or version against the patterns defined.
338 # Returns a pattern which matches (if any).
339 sub find_matching_pattern {
340     my ($self, $refsym, $sonames, $inc_deprecated) = @_;
341     $inc_deprecated //= 0;
342     my $name = (ref $refsym) ? $refsym->get_symbolname() : $refsym;
343
344     my $pattern_ok = sub {
345         my $p = shift;
346         return defined $p && ($inc_deprecated || !$p->{deprecated}) &&
347                $p->arch_is_concerned($self->get_arch());
348     };
349
350     foreach my $soname ((ref($sonames) eq 'ARRAY') ? @$sonames : $sonames) {
351         my $obj = $self->get_object($soname);
352         my ($type, $pattern);
353         next unless defined $obj;
354
355         my $all_aliases = $obj->{patterns}{aliases};
356         for my $type (Dpkg::Shlibs::Symbol::ALIAS_TYPES) {
357             if (exists $all_aliases->{$type} && keys(%{$all_aliases->{$type}})) {
358                 my $aliases = $all_aliases->{$type};
359                 my $converter = $aliases->{(keys %$aliases)[0]};
360                 if (my $alias = $converter->convert_to_alias($name)) {
361                     if ($alias && exists $aliases->{$alias}) {
362                         $pattern = $aliases->{$alias};
363                         last if &$pattern_ok($pattern);
364                         $pattern = undef; # otherwise not found yet
365                     }
366                 }
367             }
368         }
369
370         # Now try generic patterns and use the first that matches
371         if (not defined $pattern) {
372             for my $p (@{$obj->{patterns}{generic}}) {
373                 if (&$pattern_ok($p) && $p->matches_rawname($name)) {
374                     $pattern = $p;
375                     last;
376                 }
377             }
378         }
379         if (defined $pattern) {
380             return (wantarray) ?
381                 ( symbol => $pattern, soname => $soname ) : $pattern;
382         }
383     }
384     return;
385 }
386
387 # merge_symbols($object, $minver)
388 # Needs $Objdump->get_object($soname) as parameter
389 # Don't merge blacklisted symbols related to the internal (arch-specific)
390 # machinery
391 sub merge_symbols {
392     my ($self, $object, $minver) = @_;
393
394     my $soname = $object->{SONAME};
395     error(_g('cannot merge symbols from objects without SONAME'))
396         unless $soname;
397
398     my %include_groups = ();
399     my $groups = $self->get_field($soname, 'Ignore-Blacklist-Groups');
400     if (defined $groups) {
401         $include_groups{$_} = 1 foreach (split /\s+/, $groups);
402     }
403
404     my %dynsyms;
405     foreach my $sym ($object->get_exported_dynamic_symbols()) {
406         my $name = $sym->{name} . '@' .
407                    ($sym->{version} ? $sym->{version} : 'Base');
408         my $symobj = $self->lookup_symbol($name, $soname);
409         if (symbol_is_blacklisted($sym->{name}, \%include_groups)) {
410             next unless (defined $symobj and $symobj->has_tag('ignore-blacklist'));
411         }
412         $dynsyms{$name} = $sym;
413     }
414
415     unless ($self->has_object($soname)) {
416         $self->create_object($soname, '');
417     }
418     # Scan all symbols provided by the objects
419     my $obj = $self->get_object($soname);
420     # invalidate the minimum version cache - it is not sufficient to
421     # invalidate in add_symbol, since we might change a minimum
422     # version for a particular symbol without adding it
423     $obj->{minver_cache} = [];
424     foreach my $name (keys %dynsyms) {
425         my $sym;
426         if ($sym = $self->lookup_symbol($name, $obj, 1)) {
427             # If the symbol is already listed in the file
428             $sym->mark_found_in_library($minver, $self->get_arch());
429         } else {
430             # The exact symbol is not present in the file, but it might match a
431             # pattern.
432             my $pattern = $self->find_matching_pattern($name, $obj, 1);
433             if (defined $pattern) {
434                 $pattern->mark_found_in_library($minver, $self->get_arch());
435                 $sym = $pattern->create_pattern_match(symbol => $name);
436             } else {
437                 # Symbol without any special info as no pattern matched
438                 $sym = Dpkg::Shlibs::Symbol->new(symbol => $name,
439                                                  minver => $minver);
440             }
441             $self->add_symbol($sym, $obj);
442         }
443     }
444
445     # Process all symbols which could not be found in the library.
446     foreach my $sym ($self->get_symbols($soname)) {
447         if (not exists $dynsyms{$sym->get_symbolname()}) {
448             $sym->mark_not_found_in_library($minver, $self->get_arch());
449         }
450     }
451
452     # Deprecate patterns which didn't match anything
453     for my $pattern (grep { $_->get_pattern_matches() == 0 }
454                           $self->get_patterns($soname)) {
455         $pattern->mark_not_found_in_library($minver, $self->get_arch());
456     }
457 }
458
459 sub is_empty {
460     my ($self) = @_;
461     return scalar(keys %{$self->{objects}}) ? 0 : 1;
462 }
463
464 sub has_object {
465     my ($self, $soname) = @_;
466     return exists $self->{objects}{$soname};
467 }
468
469 sub get_object {
470     my ($self, $soname) = @_;
471     return ref($soname) ? $soname : $self->{objects}{$soname};
472 }
473
474 sub create_object {
475     my ($self, $soname, @deps) = @_;
476     $self->{objects}{$soname} = {
477         syms => {},
478         fields => {},
479         patterns => {
480             aliases => {},
481             generic => [],
482         },
483         deps => [ @deps ],
484         minver_cache => []
485     };
486 }
487
488 sub get_dependency {
489     my ($self, $soname, $dep_id) = @_;
490     $dep_id //= 0;
491     return $self->get_object($soname)->{deps}[$dep_id];
492 }
493
494 sub get_smallest_version {
495     my ($self, $soname, $dep_id) = @_;
496     $dep_id //= 0;
497     my $so_object = $self->get_object($soname);
498     return $so_object->{minver_cache}[$dep_id]
499         if defined $so_object->{minver_cache}[$dep_id];
500     my $minver;
501     foreach my $sym ($self->get_symbols($so_object)) {
502         next if $dep_id != $sym->{dep_id};
503         $minver //= $sym->{minver};
504         if (version_compare($minver, $sym->{minver}) > 0) {
505             $minver = $sym->{minver};
506         }
507     }
508     $so_object->{minver_cache}[$dep_id] = $minver;
509     return $minver;
510 }
511
512 sub get_dependencies {
513     my ($self, $soname) = @_;
514     return @{$self->get_object($soname)->{deps}};
515 }
516
517 sub get_field {
518     my ($self, $soname, $name) = @_;
519     if (my $obj = $self->get_object($soname)) {
520         if (exists $obj->{fields}{$name}) {
521             return $obj->{fields}{$name};
522         }
523     }
524     return;
525 }
526
527 # Tries to find a symbol like the $refsym and returns its descriptor.
528 # $refsym may also be a symbol name.
529 sub lookup_symbol {
530     my ($self, $refsym, $sonames, $inc_deprecated) = @_;
531     $inc_deprecated //= 0;
532     my $name = (ref $refsym) ? $refsym->get_symbolname() : $refsym;
533
534     foreach my $so ((ref($sonames) eq 'ARRAY') ? @$sonames : $sonames) {
535         if (my $obj = $self->get_object($so)) {
536             my $sym = $obj->{syms}{$name};
537             if ($sym and ($inc_deprecated or not $sym->{deprecated}))
538             {
539                 return (wantarray) ?
540                     ( symbol => $sym, soname => $so ) : $sym;
541             }
542         }
543     }
544     return;
545 }
546
547 # Tries to find a pattern like the $refpat and returns its descriptor.
548 # $refpat may also be a pattern spec.
549 sub lookup_pattern {
550     my ($self, $refpat, $sonames, $inc_deprecated) = @_;
551     $inc_deprecated //= 0;
552     # If $refsym is a string, we need to create a dummy ref symbol.
553     $refpat = $self->create_symbol($refpat, dummy => 1) if ! ref($refpat);
554
555     if ($refpat && $refpat->is_pattern()) {
556         foreach my $soname ((ref($sonames) eq 'ARRAY') ? @$sonames : $sonames) {
557             if (my $obj = $self->get_object($soname)) {
558                 my $pat;
559                 if (my $type = $refpat->get_alias_type()) {
560                     if (exists $obj->{patterns}{aliases}{$type}) {
561                         $pat = $obj->{patterns}{aliases}{$type}{$refpat->get_symbolname()};
562                     }
563                 } elsif ($refpat->get_pattern_type() eq 'generic') {
564                     for my $p (@{$obj->{patterns}{generic}}) {
565                         if (($inc_deprecated || !$p->{deprecated}) &&
566                             $p->equals($refpat, versioning => 0))
567                         {
568                             $pat = $p;
569                             last;
570                         }
571                     }
572                 }
573                 if ($pat && ($inc_deprecated || !$pat->{deprecated})) {
574                     return (wantarray) ?
575                         (symbol => $pat, soname => $soname) : $pat;
576                 }
577             }
578         }
579     }
580     return;
581 }
582
583 # Get symbol object reference either by symbol name or by a reference object.
584 sub get_symbol_object {
585     my ($self, $refsym, $soname) = @_;
586     my $sym = $self->lookup_symbol($refsym, $soname, 1);
587     if (! defined $sym) {
588         $sym = $self->lookup_pattern($refsym, $soname, 1);
589     }
590     return $sym;
591 }
592
593 sub get_new_symbols {
594     my ($self, $ref, %opts) = @_;
595     my $with_optional = (exists $opts{with_optional}) ?
596         $opts{with_optional} : 0;
597     my @res;
598     foreach my $soname ($self->get_sonames()) {
599         next if not $ref->has_object($soname);
600
601         # Scan raw symbols first.
602         foreach my $sym (grep { ($with_optional || ! $_->is_optional())
603                                 && $_->is_legitimate($self->get_arch()) }
604                               $self->get_symbols($soname))
605         {
606             my $refsym = $ref->lookup_symbol($sym, $soname, 1);
607             my $isnew;
608             if (defined $refsym) {
609                 # If the symbol exists in the $ref symbol file, it might
610                 # still be new if $refsym is not legitimate.
611                 $isnew = not $refsym->is_legitimate($self->get_arch());
612             } else {
613                 # If the symbol does not exist in the $ref symbol file, it does
614                 # not mean that it's new. It might still match a pattern in the
615                 # symbol file. However, due to performance reasons, first check
616                 # if the pattern that the symbol matches (if any) exists in the
617                 # ref symbol file as well.
618                 $isnew = not (
619                     ($sym->get_pattern() and $ref->lookup_pattern($sym->get_pattern(), $soname, 1)) or
620                     $ref->find_matching_pattern($sym, $soname, 1)
621                 );
622             }
623             push @res, { symbol => $sym, soname => $soname } if $isnew;
624         }
625
626         # Now scan patterns
627         foreach my $p (grep { ($with_optional || ! $_->is_optional())
628                               && $_->is_legitimate($self->get_arch()) }
629                             $self->get_patterns($soname))
630         {
631             my $refpat = $ref->lookup_pattern($p, $soname, 0);
632             # If reference pattern was not found or it is not legitimate,
633             # considering current one as new.
634             if (not defined $refpat or
635                 not $refpat->is_legitimate($self->get_arch()))
636             {
637                 push @res, { symbol => $p , soname => $soname };
638             }
639         }
640     }
641     return @res;
642 }
643
644 sub get_lost_symbols {
645     my ($self, $ref, %opts) = @_;
646     return $ref->get_new_symbols($self, %opts);
647 }
648
649
650 sub get_new_libs {
651     my ($self, $ref) = @_;
652     my @res;
653     foreach my $soname ($self->get_sonames()) {
654         push @res, $soname if not $ref->get_object($soname);
655     }
656     return @res;
657 }
658
659 sub get_lost_libs {
660     my ($self, $ref) = @_;
661     return $ref->get_new_libs($self);
662 }
663
664 1;